'============================================================
'同步对比删除脚本
'BY:心灵
'QQ:27407749
'============================================================

dim sdir,ddir
'远程目录
sdir="\\192.168.0.200\vbs\zz\" 
'本地目录 
ddir="c:\c" 
function comparefile(sdir,ddir)
   dim Fso,dFol,dfs,sf1,f1
   set Fso=CreateObject("Scripting.FileSystemObject")
   if not(Fso.folderexists(sdir)) then 
      msgbox chr(34) &sdir &chr(34) &"文件夹不存在，请确认！",64
      exit function
   end if
   if not(Fso.folderexists(ddir)) then 
      msgbox chr(34) &ddir &"""文件夹不存在，请确认！",64
      exit function
   end if
   if right(sdir,1)<>"\" then sdir=sdir &"\"

   set dFol=fso.getfolder(ddir)
   set dfs=dfol.files

   for each f1 in dfs
       if fso.fileexists(sdir & f1.name)  then
           set sf1=fso.GetFile(sdir & f1.name)
           if f1.DateLastModified <>sf1.DateLastModified or f1.size<>sf1.size then
               f1.delete
           end if
        else
           f1.Delete(true)
        end if 
    next
   dim fols
   set fols=dfol.subfolders
   for each f1 in fols
       if not fso.folderexists(sdir &f1.name) then
            f1.delete true
       else     
          comparefile sdir & f1.name,f1.path
       end if
   next
end function
comparefile sdir,ddir